[Setup]
AppName=X-Chat 2
AppVerName=X-Chat 2.8.4-1
AppVersion=2.8.4-1
VersionInfoVersion=2.8.4
AppPublisher=SilvereX
AppPublisherURL=http://www.silverex.info/
AppCopyright=Copyright (C) 1998-2007 Peter Zelezny & Vaidrius Petrauskas
AppSupportURL=http://www.xchat.org/
AppUpdatesURL=http://www.silverex.info/
DefaultDirName={pf}\X-Chat 2
DefaultGroupName=X-Chat 2
LicenseFile=license.txt
Compression=lzma/ultra
SolidCompression=yes
InternalCompressLevel=ultra
SourceDir=.
OutputDir=.
OutputBaseFilename=xchat-2.8.4-1
ChangesEnvironment=yes
FlatComponentsList=no

[Types]
Name: "normal"; Description: "Normal installation"
Name: "compact"; Description: "Compact installation"
Name: "full"; Description: "Full installation"
Name: "custom"; Description: "Custom installation"; Flags: iscustom

[Components]
Name: "xchat"; Description: "X-Chat 2 Program Files"; Types: compact normal full custom; Flags: fixed
Name: "gtk"; Description: "Interface Libraries (GTK+ 2.10.9)"; Types: compact normal full custom
Name: "openssl"; Description: "Encryption Libraries (OpenSSL 0.9.8e)"; Types: normal full custom
Name: "translations"; Description: "Interface Translations"; Types: normal full custom
;Name: "xtray"; Description: "System Tray Icon (xTray 1.2.2 PR)"; Types: normal full custom
Name: "plugins"; Description: "Scripting Plugins"; Types: normal full custom
Name: "plugins\perl"; Description: "Perl (needs ActivePerl 5.8)"; Types: normal full custom
;Name: "plugins\python"; Description: "Python (needs Python 2.4)"; Types: normal full custom
Name: "plugins\ruby"; Description: "Ruby (needs Ruby 1.8)"; Types: full custom
Name: "plugins\tcl"; Description: "Tcl (needs ActiveTcl 8.4)"; Types: normal full custom

[Tasks]
Name: "desktopicon"; Description: "Create a &desktop icon"; GroupDescription: "Additional icons:"; Components: xchat; Flags: unchecked
Name: "quicklaunchicon"; Description: "Create a &Quick Launch icon"; GroupDescription: "Additional icons:"; Components: xchat

[Registry]
Root: HKCU; Subkey: "Software\Microsoft\Windows\CurrentVersion\App Paths\xchat.exe"; Flags: uninsdeletekey; Components: gtk
Root: HKCU; Subkey: "Software\Microsoft\Windows\CurrentVersion\App Paths\xchat.exe"; ValueType: string; ValueData: "{app}\xchat.exe"; Flags: uninsdeletevalue; Components: gtk
Root: HKCU; Subkey: "Software\Microsoft\Windows\CurrentVersion\App Paths\xchat.exe"; ValueType: string; ValueName: "Path"; ValueData: "{app}\lib"; Flags: uninsdeletevalue; Components: gtk
Root: HKLM; Subkey: "Software\Microsoft\Windows\CurrentVersion\App Paths\xchat.exe"; Flags: uninsdeletekey; Components: gtk
Root: HKLM; Subkey: "Software\Microsoft\Windows\CurrentVersion\App Paths\xchat.exe"; ValueType: string; ValueData: "{app}\xchat.exe"; Flags: uninsdeletevalue; Components: gtk
Root: HKLM; Subkey: "Software\Microsoft\Windows\CurrentVersion\App Paths\xchat.exe"; ValueType: string; ValueName: "Path"; ValueData: "{app}\lib"; Flags: uninsdeletevalue; Components: gtk
Root: HKCU; Subkey: "Software\Microsoft\Windows\CurrentVersion\App Paths\gtk2_prefs.exe"; Flags: uninsdeletekey; Components: gtk
Root: HKCU; Subkey: "Software\Microsoft\Windows\CurrentVersion\App Paths\gtk2_prefs.exe"; ValueType: string; ValueData: "{app}\lib\gtk2_prefs.exe"; Flags: uninsdeletevalue; Components: gtk
Root: HKCU; Subkey: "Software\Microsoft\Windows\CurrentVersion\App Paths\gtk2_prefs.exe"; ValueType: string; ValueName: "Path"; ValueData: "{app}\lib"; Flags: uninsdeletevalue; Components: gtk
Root: HKLM; Subkey: "Software\Microsoft\Windows\CurrentVersion\App Paths\gtk2_prefs.exe"; Flags: uninsdeletekey; Components: gtk
Root: HKLM; Subkey: "Software\Microsoft\Windows\CurrentVersion\App Paths\gtk2_prefs.exe"; ValueType: string; ValueData: "{app}\lib\gtk2_prefs.exe"; Flags: uninsdeletevalue; Components: gtk
Root: HKLM; Subkey: "Software\Microsoft\Windows\CurrentVersion\App Paths\gtk2_prefs.exe"; ValueType: string; ValueName: "Path"; ValueData: "{app}\lib"; Flags: uninsdeletevalue; Components: gtk
Root: HKCU; Subkey: "Environment"; ValueType: string; ValueName: "XCHAT_WARNING_IGNORE"; ValueData: "true"; Flags: uninsdeletevalue

Root: HKCR; Subkey: "irc"; ValueType: none; ValueName: ""; ValueData: ""; Flags: deletekey uninsdeletekey
Root: HKCR; Subkey: "irc"; ValueType: string; ValueName: ""; ValueData: "URL:IRC Protocol"; Flags: uninsdeletevalue
Root: HKCR; Subkey: "irc"; ValueType: dword; ValueName: "BrowserFlags"; ValueData: 8; Flags: uninsdeletevalue
Root: HKCR; Subkey: "irc"; ValueType: dword; ValueName: "EditFlags"; ValueData: 2; Flags: uninsdeletevalue
Root: HKCR; Subkey: "irc"; ValueType: string; ValueName: "URL Protocol"; ValueData: ""; Flags: uninsdeletevalue
Root: HKCR; Subkey: "irc\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\xchat.exe,0"; Flags: uninsdeletevalue
Root: HKCR; Subkey: "irc\shell"; ValueType: string; ValueName: ""; ValueData: "open"; Flags: uninsdeletevalue
Root: HKCR; Subkey: "irc\shell\open\command"; ValueType: string; ValueName: ""; ValueData: "{app}\xchat.exe ""%1"""; Flags: uninsdeletevalue

Root: HKCR; Subkey: "ircs"; ValueType: none; ValueName: ""; ValueData: ""; Flags: deletekey uninsdeletekey
Root: HKCR; Subkey: "ircs"; ValueType: string; ValueName: ""; ValueData: "URL:IRC SSL Protocol"; Flags: uninsdeletevalue
Root: HKCR; Subkey: "ircs"; ValueType: dword; ValueName: "BrowserFlags"; ValueData: 8; Flags: uninsdeletevalue
Root: HKCR; Subkey: "ircs"; ValueType: dword; ValueName: "EditFlags"; ValueData: 2; Flags: uninsdeletevalue
Root: HKCR; Subkey: "ircs"; ValueType: string; ValueName: "URL Protocol"; ValueData: ""; Flags: uninsdeletevalue
Root: HKCR; Subkey: "ircs\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\xchat.exe,0"; Flags: uninsdeletevalue
Root: HKCR; Subkey: "ircs\shell"; ValueType: string; ValueName: ""; ValueData: "open"; Flags: uninsdeletevalue
Root: HKCR; Subkey: "ircs\shell\open\command"; ValueType: string; ValueName: ""; ValueData: "{app}\xchat.exe ""%1"""; Flags: uninsdeletevalue

[Files]
Source: "fe-gtk\xchat.exe"; DestDir: "{app}"; Components: xchat
Source: "license.txt"; DestDir: "{app}"; Components: xchat
Source: "ChangeLog"; DestDir: "{app}"; DestName: "ChangeLog.txt"; Components: xchat
Source: "libeay32.dll"; DestDir: "{app}"; Components: openssl
Source: "ssleay32.dll"; DestDir: "{app}"; Components: openssl
Source: "fsex2p00_public.ttf"; DestDir: "{fonts}"; Flags: onlyifdoesntexist uninsneveruninstall; FontInstall: "Fixedsys Excelsior 2.00"; Components: xchat
Source: "plugins\xcperl.dll"; DestDir: "{app}\plugins"; Components: plugins\perl
;Source: "plugins\xcpython.dll"; DestDir: "{app}\plugins"; Components: plugins\python
;Source: "plugins\xcpython.mod"; DestDir: "{app}\plugins"; Components: plugins\python
Source: "plugins\xcruby.dll"; DestDir: "{app}\plugins"; Components: plugins\ruby
Source: "plugins\rubyenv.ini"; DestDir: "{app}\plugins"; Components: plugins\ruby
Source: "plugins\xctcl.dll"; DestDir: "{app}\plugins"; Components: plugins\tcl
Source: "plugins\xcdns.dll"; DestDir: "{app}\plugins"; Components: xchat
Source: "plugins\xcexec.dll"; DestDir: "{app}\plugins"; Components: xchat
Source: "plugins\xcwinamp.dll"; DestDir: "{app}\plugins"; Components: xchat
;Source: "plugins\xtray.dll"; DestDir: "{app}\plugins"; Components: xtray

Source: "gtk\*"; DestDir: "{app}"; Flags: createallsubdirs recursesubdirs; Components: gtk
Source: "gtk\lib\iconv.dll"; DestDir: "{app}"; Components: gtk
Source: "update-modules.bat"; DestDir: "{tmp}"; Components: gtk
Source: "update-loaders.bat"; DestDir: "{tmp}"; Components: gtk

Source: "locale\*"; DestDir: "{app}\locale"; Flags: createallsubdirs recursesubdirs; Components: translations
Source: "gtk-locale\*"; DestDir: "{app}\lib\locale"; Flags: createallsubdirs recursesubdirs; Components: gtk and translations

[Run]
Filename: "{tmp}\update-modules.bat"; Parameters: """{app}\lib\gtk-query-immodules-2.0.exe"" ""{app}\etc\gtk-2.0\gtk.immodules"""; StatusMsg: "Updating GTK+ input modules..."; WorkingDir: "{app}\lib"; Flags: waituntilterminated runhidden; Components: gtk
Filename: "{tmp}\update-loaders.bat"; Parameters: """{app}\lib\gdk-pixbuf-query-loaders.exe"" ""{app}\etc\gtk-2.0\gdk-pixbuf.loaders"""; StatusMsg: "Updating GTK+ image loaders..."; WorkingDir: "{app}\lib"; Flags: waituntilterminated runhidden; Components: gtk
Filename: "{tmp}\update-modules.bat"; Parameters: """{app}\lib\pango-querymodules.exe"" ""{app}\etc\pango\pango.modules"""; StatusMsg: "Updating Pango modules..."; WorkingDir: "{app}\lib"; Flags: waituntilterminated runhidden; Components: gtk

[UninstallDelete]
Type: files; Name: "{app}\etc\gtk-2.0\gtk.immodules"
Type: files; Name: "{app}\etc\gtk-2.0\gdk-pixbuf.loaders"
Type: files; Name: "{app}\etc\pango\pango.modules"

[Icons]
Name: "{group}\X-Chat 2"; Filename: "{app}\xchat.exe"; Comment: "IRC Client"; WorkingDir: "{app}"; Flags: runmaximized
Name: "{group}\X-Chat 2 for Windows Web Site"; Filename: "http://www.silverex.info/";
Name: "{group}\X-Chat 2 Web Site"; Filename: "http://www.xchat.org/";
Name: "{group}\Uninstall X-Chat 2"; Filename: "{uninstallexe}";
Name: "{group}\Theme Utility"; Filename: "{app}\lib\gtk2_prefs.exe"; IconFilename: "{app}\lib\gtk2_prefs.ico"; Components: gtk
Name: "{userdesktop}\X-Chat 2"; Filename: "{app}\xchat.exe"; Tasks: desktopicon; Comment: "IRC Client";  WorkingDir: "{app}";
Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\X-Chat 2"; Filename: "{app}\xchat.exe"; Tasks: quicklaunchicon; Comment: "IRC Client";  WorkingDir: "{app}";

[Messages]
BeveledLabel= X-Chat 2 Installer for Windows